COMMENT This program will be called by Program I. 

COMMENT Save as the calling name (indicated in purple) in program I Proceed with the COMMENT indicated changes.

COMMENT Highlighted portions of the program will need to be changed accordingly.

COMMENT Variable Set  Number of Cases  Number of Variables.
COMMENT Variables correspond to the number of factors. 
COMMENT Change these according to the given format.
COMMENT NOTE Commas exist between Fact_n
set mxloop=50000 results=none highres=off  cache 100000 compression = on mprint=off .

set printback=none workspace=40000.

get file='c:\holz.sav'.

COMMENT Resample with Replacement.

input program.

loop #i=1 to  301   .

compute seqnum=trunc(uniform(  301  ))+1.

end case.

end loop.

end file.

end input program.

sort cases by seqnum.

match files file=* /tables='c:\holz.sav'/by seqnum.

execute.

save outfile='c:\fact.sav'.

FACTOR 

 /MATRIX=OUT (FAC='c:\bootfac10.sav') 

 /VARIABLES T6 T7 T9 T10 T12 T13 T14 T15 T17      

 /MISSING listwise

 /ANALYSIS T6 T7 T9 T10 T12 T13 T14 T15 T17        

  /PRINT INITIAL EXTRACTION ROTATION

  /CRITERIA FACTORS(3) ITERATE(25)

  /EXTRACTION PC

  /CRITERIA ITERATE(25)

  /ROTATION VARIMAX

  /METHOD=CORRELATION . 

get file='c:\fact.sav'.

correlations variables= T6 T7 T9 T10 T12 T13 T14 T15 T17      /matrix=out('c:\corr2.sav').

get file='c:\corr2.sav'.

SORT CASES BY rowtype_ (A) .

FILTER OFF.

use 1 thru 9 .

EXECUTE .

flip variables= T6 T7 T9 T10 T12 T13 T14 T15 T17      .

MATRIX.

get m /variables=var001 to var009 .

print m.

CALL EIGEN(m,A,B).

print B.

COMPUTE B_T=TRANSPOS(B) .

save B_T /outfile='c:\eigenvorig.sav'.

END MATRIX.

get file='c:\b1.sav'.

get file='c:\bootfac10.sav'.

FLIP

  VARIABLES= T6 T7 T9 T10 T12 T13 T14 T15 T17    .

RENAME VARIABLES var001=FACT_1 var002=FACT_2  var003=FACT_3    .

numeric seqnum(f1)  .

leave seqnum.

compute seqnum=sum(seqnum,1).

leave seqnum.

execute.

sort cases by seqnum.

match files file=* /tables='c:\b1.sav'/by seqnum.

execute.

MATRIX .

GET A/VARIABLES=b1 b2   b3.

GET B/variables= FACT_1 FACT_2   FACT_3.

print B.

print A.

COMMENT PROCRUSTEAN ROTATION BY BRUCE THOMPSON.
COMPUTE N_A =make(9,1,0).

print N_A.

COMPUTE DIAG_M =make(3,3,0).

PRINT DIAG_M.

COMPUTE N_B=N_A .

PRINT A /

  FORMAT='F8.2' /

  TITLE='First Pattern Matrix (Target)' /

  SPACE=4/

  RLABELS= T6 T7 T9 T10 T12 T13 T14 T15 T17        /

  CLABELS=Fact_I, Fact_II    , Fact_III / .

COMPUTE A_N=A .

- LOOP #I=1 TO NROW(A) .

-   LOOP #J=1 TO NCOL(A) .

-      COMPUTE A_N(#I,#J)=A(#I,#J) ** 2 .

-   END LOOP .

-END LOOP .

PRINT A_N /

 FORMAT='F8.4' /

 TITLE='First Pattern Matrix (Target) Squared' /

 SPACE=4 /

 RLABELS= T6 T7 T9 T10 T12 T13 T14 T15 T17     /

 CLABELS=Fact_I, Fact_II   , Fact_III / .

-LOOP #J=1 TO NCOL(A) .

+ LOOP #I=1 TO NROW(A) .

COMPUTE N_A(#I)=A_N(#I,#J) + N_A(#I) .

+ END LOOP .

-END LOOP .

PRINT N_A /

 FORMAT='F8.3' /

 TITLE='Row Sum of Squares for First Pattern Matrix' /

 SPACE=4 /

 RLABELS= T6 T7 T9 T10 T12 T13 T14 T15 T17      / .

LOOP #I=1 TO NROW(A) .

- COMPUTE N_A(#I) = 1.0 / (N_A(#I) ** .5) .

END LOOP .

PRINT N_A /

 FORMAT='F8.3' /

 TITLE='Normalization Factor for Rows' /

 SPACE=4 /

 RLABELS= T6 T7 T9 T10 T12 T13 T14 T15 T17     / .

LOOP #J=1 TO NCOL(A) .

+ LOOP #I=1 TO NROW(A) .

COMPUTE A_N(#I,#J)=A(#I,#J) * N_A(#I) .

+ END LOOP .

END LOOP .

PRINT A_N /

 FORMAT='F8.4' /

 TITLE='First Pattern Matrix (Target) Normalized' /

 SPACE=4 /

 RLABELS= T6 T7 T9 T10 T12 T13 T14 T15 T17        /

 CLABELS=Fact_I, Fact_II   , Fact_III / .

PRINT B /

 FORMAT='F8.2' /

 TITLE='Second Pattern Matrix' /

 SPACE=4 /

 RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17        /

 CLABELS=Fact_I, Fact_II   , Fact_III / .

COMPUTE B_N=B .

-LOOP #I=1 TO NROW(B) .

+ LOOP #J=1 TO NCOL(B) .

COMPUTE B_N(#I,#J)=B(#I,#J) ** 2 .

+ END LOOP .

-END LOOP .

PRINT B_N /

 FORMAT='F8.4' /

 TITLE='Second Pattern Matrix Squared' /

 SPACE=4 /

 RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17     /

 CLABELS=Fact_I, Fact_II   , Fact_III / .

-LOOP #J=1 TO NCOL(B) .

+ LOOP #I=1 TO NROW(B) .

COMPUTE N_B(#I)=B_N(#I,#J) + N_B(#I) .

+ END LOOP .

-END LOOP .

PRINT N_B /

 FORMAT='F8.3' /

 TITLE='Row Sum of Squares for Second Pattern Matrix' /

 SPACE=4 /

 RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17    / .

LOOP #I=1 TO NROW(B) .

- COMPUTE N_B(#I) = 1.0 / (N_B(#I) ** .5) .

END LOOP .

PRINT N_B / FORMAT='F8.3' /

 TITLE='Normalization Factor for Rows' /

 SPACE=4 /

 RLABELS=   T6 T7 T9 T10 T12 T13 T14 T15 T17   / .

LOOP #J=1 TO NCOL(B) .

+ LOOP #I=1 TO NROW(B) .

COMPUTE B_N(#I,#J)=B(#I,#J) * N_B(#I) .

+ END LOOP .

END LOOP .

PRINT B_N / FORMAT='F8.4' /

 TITLE='Second Pattern Matrix Normalized' /

 SPACE=4 /

 RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17    /

 CLABELS=Fact_I, Fact_II  , Fact_III / .

COMPUTE A_T=TRANSPOS(A_N) .

PRINT A_T / FORMAT='F8.2' /

 TITLE='A_N Transpose' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II  , Fact_III /

 CLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17    / .

COMPUTE B_T=TRANSPOS(B_N) .

PRINT B_T / FORMAT='F8.2' /

 TITLE='B_N Transpose' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II  , Fact_III /

 CLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17    / .

COMPUTE RI=A_T * B_N .

PRINT RI / FORMAT='F8.3' /

 TITLE='A_N Transpose times B_N' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II  , Fact_III /

 CLABELS=Fact_I, Fact_II   , Fact_III / .

COMPUTE RI_T=TRANSPOS(RI) .

PRINT RI_T / FORMAT='F8.3' /

 TITLE='Transpose of (A_N Transpose times B_N)' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II  , Fact_III /

 CLABELS=Fact_I, Fact_II  , Fact_III / .

COMPUTE QUAD=RI * RI_T .

PRINT QUAD / FORMAT='F8.3' /

 TITLE='A_N Trans * B_N * Trans of (A_N Trans * B_N)' /

 SPACE=2 /

 RLABELS=Fact_I, Fact_II  , Fact_III /

 CLABELS=Fact_I, Fact_II   , Fact_III / .

CALL EIGEN(QUAD, EIGVEC, EIG) .

PRINT EIG / FORMAT='F8.3' /

 TITLE='Eigenvalues of QUAD' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II   , Fact_III / .

PRINT EIGVEC / FORMAT='F8.3' /

 TITLE='Eigenvectors of QUAD' /

 SPACE=4 /

 RLABELS=ONE, TWO   , THREE /
 CLABELS=Fact_I, Fact_II   , Fact_III / .

-LOOP #I=1 TO NROW(QUAD) .

+ LOOP #J=1 TO NROW(QUAD) .

COMPUTE EIGVEC(#I,#J)=EIGVEC(#I,#J) * (EIG(#J) ** .5) .

+ END LOOP .

-END LOOP .

PRINT EIGVEC / FORMAT='F8.3' /

 TITLE='Pattern Coefficients of QUAD' /

 SPACE=4 /

 RLABELS=ONE, TWO  , THREE/

 CLABELS=Fact_I, Fact_II    , Fact_III / .

LOOP I=1 TO NROW(EIG) .

- COMPUTE EIG(I)=EIG(I) ** -1.5 .

END LOOP .

PRINT EIG / FORMAT='F8.3' /

 TITLE='Eigenvalues raised to -1.5' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II   , Fact_III / .

CALL SETDIAG(DIAG_M,EIG) .

PRINT DIAG_M / FORMAT='F8.3' /

 TITLE='Diagonal Matrix (Eigenvalues raised to -1.5)' /

 SPACE=4 /

 CLABELS=Fact_I, Fact_II    , Fact_III /

 RLABELS=Fact_I, Fact_II   , Fact_III / .

COMPUTE VEC_T=TRANSPOS(EIGVEC) .

PRINT VEC_T / FORMAT='F8.3' /

 TITLE='Transpose of Eigenvectors' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II   , Fact_III /

 CLABELS=ONE, TWO  , THREE / .

COMPUTE D=RI_T * EIGVEC .

PRINT D / FORMAT='F9.3' /

 TITLE='D= trans (trans A times B) times Eigenvectors' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II   , Fact_III /

 CLABELS=Fact_I, Fact_I   , Fact_III / .

LOOP J=1 TO NCOL(A) .

- COMPUTE EE=EIG(J) .

- LOOP I=1 TO NCOL(A) .

-   COMPUTE D(I,J)=D(I,J) * EE .

- END LOOP .

END LOOP .

PRINT D / FORMAT='F9.3' /

 TITLE='D = D times Eigenvalues ** -1.5' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II  , Fact_III /

 CLABELS=Fact_I, Fact_II  , Fact_III / .

COMPUTE D_T=TRANSPOS(D) .

PRINT D_T / FORMAT='F9.3' /

 TITLE='D transposed' /

 SPACE=4 /

 RLABELS=Fact_I, Fact_II  , Fact_III /

 CLABELS=Fact_I, Fact_II   , Fact_III / .

COMPUTE C=EIGVEC * D_T .

PRINT C / FORMAT='F9.3' /

 TITLE='Factor Correlations (Cosines)' /

 SPACE=4 / RLABELS=Fact_Ia, Fact_IIa  , Fact_IIIa/

 CLABELS=Fact_Ib, Fact_IIb  , Fact_IIIb/ .

COMPUTE C=D * VEC_T .

COMPUTE B_ROT=B * C .

PRINT B_ROT / FORMAT='F8.3' /

 TITLE='B rotated to Best-Fit with A' /

 SPACE=2 / RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17   /

 CLABELS=Fact_I, Fact_II   , Fact_III / .

COMPUTE BROT_N=B_ROT .

LOOP #I=1 TO NROW(A) .

-  LOOP #J=1 TO NCOL(A) .

-     COMPUTE BROT_N(#I,#J)=B_ROT(#I,#J) ** 2 .

-  END LOOP .

COMPUTE N_A(#I)= .0 .

END LOOP .

PRINT BROT_N / FORMAT='F8.4' /

 TITLE='Best Fit Pattern Matrix (Target) Squared' /

 SPACE=4 / RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17   /

 CLABELS=Fact_I, Fact_II  , Fact_III .

-LOOP #J=1 TO NCOL(A) .

+ LOOP #I=1 TO NROW(A) .

COMPUTE N_A(#I)=BROT_N(#I,#J) + N_A(#I) .

+ END LOOP .

-END LOOP .

PRINT N_A / FORMAT='F8.3' /

 TITLE='Row Sum of Squares for Best Fit Matrix' /

 SPACE=4 / RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17     / .

LOOP #I=1 TO NROW(A) .

- COMPUTE N_A(#I) = 1.0 / (N_A(#I) ** .5) .

END LOOP .

PRINT N_A / FORMAT='F8.3' /

 TITLE='Normalization Factor for Rows' /

 SPACE=4 / RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17       / .

-LOOP #J=1 TO NCOL(A) .

+ LOOP #I=1 TO NROW(A) .

COMPUTE BROT_N(#I,#J)=B_ROT(#I,#J) * N_A(#I) .

+ END LOOP .

-END LOOP .

PRINT BROT_N / FORMAT='F8.4' /

 TITLE='Best Fit Pattern Matrix (Target) Normalized' /

 SPACE=4 /  RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17     /

 CLABELS=Fact_I, Fact_II   , Fact_III/ .

COMPUTE BROTN_T=TRANSPOS(BROT_N) .

COMPUTE T_M=A_N * BROTN_T .

COMPUTE TEST=DIAG(T_M) .

PRINT TEST / FORMAT='F8.3' /

 TITLE='Test Vector Cosines for Variables' /

 SPACE=4 /  RLABELS=  T6 T7 T9 T10 T12 T13 T14 T15 T17    / .

SAVE BROTN_T /OUTFILE='C:\brotorig.SAV'.

END MATRIX .

get file='c:\brotorig.sav'.

dataset name active5 .

numeric seqnum(f1)  .

leave seqnum.

compute seqnum=sum(seqnum,1).

leave seqnum.

execute.

dataset close active5 .

save outfile='c:\brotorig.sav'.

